sys-auth/libnss-mysql/libnss-mysql-1.5_p20060915-r1.ebuild (ca69549)

libnss-mysql-1.5_p20060915-r1.ebuild

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/libnss-mysql/libnss-mysql-1.5_p20060915.ebuild,v 1.1 2010/02/23 12:43:44 hanno Exp $

EAPI=2

inherit multilib

KEYWORDS="~amd64 ~ppc ~sparc ~x86"

DESCRIPTION="NSS MySQL Library."
HOMEPAGE="http://libnss-mysql.sourceforge.net/"
SRC_URI="http://libnss-mysql.sourceforge.net/snapshot/${PN}-${PV/1.5_p/}.tgz"
LICENSE="GPL-2"
SLOT="0"
IUSE="debug"

DEPEND="virtual/mysql"
S="${WORKDIR}/${PN}"

src_configure() {
	local myconf=""

# use_enable doesn't work due to a bug in the configure script
	# that enables debug also with --disable-debug
	use debug && myconf="--enable-debug"

# authentication libraries don't belong into usr,
	# please don't change this
	econf --libdir="/$(get_libdir)" \
		$myconf
}

src_install() {
	emake DESTDIR="${D}" install || die

find "${D}" -name '*.la' -delete

newdoc sample/README README.sample
	dodoc AUTHORS DEBUGGING FAQ INSTALL NEWS README THANKS \
		TODO UPGRADING ChangeLog

for subdir in sample/{linux,freebsd,complex,minimal} ; do
		docinto "${subdir}"
		dodoc "${subdir}/"{*.sql,*.cfg}
	done
}

keks-overlay.git

libnss-mysql test ohne debug