# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/centericq/centericq-4.21.0-r2.ebuild,v 1.7 2006/02/17 16:38:52 blubb Exp $

inherit eutils autotools

IUSE="bidi nls ssl crypt icq jabber aim msn yahoo irc rss lj"

DESCRIPTION="A ncurses ICQ/Yahoo!/AIM/IRC/MSN/Jabber/GaduGadu/RSS/LiveJournal Client"
SRC_URI="http://thekonst.net/download/${P}.tar.bz2"
HOMEPAGE="http://thekonst.net/en/centericq"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="amd64 hppa ppc ~ppc64 sparc x86"

DEPEND="virtual/libc
	>=sys-libs/ncurses-5.2
	bidi? ( dev-libs/fribidi )
	jabber? ( crypt? ( >=app-crypt/gpgme-1.0.2 ) )
	ssl? ( >=dev-libs/openssl-0.9.6g )
	msn? ( net-misc/curl )"

RDEPEND="${DEPEND}
	nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${A}
	cd ${S}

	use amd64 && epatch ${FILESDIR}/${PN}-amd64.patch

	# fix bug #100519
	epatch ${FILESDIR}/${P}-icq-short-read.diff
	epatch ${FILESDIR}/${P}-memory-handling.diff

	# fix bug #114038
	epatch ${FILESDIR}/${P}-ktools.diff
	epatch ${FILESDIR}/${P}-sha-amd64.diff
}

src_compile() {
	if use msn && ! use ssl; then
		eerror "USE-flag collision"
		eerror "------------------"
		eerror "The \"msn\" USE-flag is set but the \"ssl\" USE-flag is"
		eerror "missing. Please set the USE-flag \"ssl\" or deactivate "
		eerror "\"msn\"."
	fi
	local myopts="--disable-konst\
	$(use_with ssl) \
	$(use_with bidi fribidi) \
	$(use_enable icq) \
	$(use_with crypt gpgme) \
	$(use_enable aim) \
	$(use_enable msn) \
	$(use_enable jabber) \
	$(use_enable yahoo) \
	$(use_enable irc) \
	$(use_enable rss) \
	$(use_enable lj)"
	
	for afile in */configure.in
	do
		pushd $(dirname ${afile})
		eautoconf || die
		popd
	done
	econf ${myopts} || die "Configure failed"
	emake || die "Compilation failed"
}

src_install () {
	einstall || die "Installation failed"
	dodoc ABOUT-NLS AUTHORS ChangeLog COPYING FAQ README THANKS TODO
}